史上最全面的多條件查詢教程

在日常工作中，最常用的功能是查詢。如果是單條件查詢，我們可以用vlookup函數進行查詢，一步到位，快速定位。

vlookup函數語法：

VLOOKUP(lookup_value,table_array,col_index_num,range_lookup)

特別注意：第三個參數是返回數據在查找區域的第幾列，而不是在原報表第幾列。最後一個參數如果是0，就是精確查找，反之為模糊查找。

在現實中，如果遇到多條件查詢，那麼我們應該怎麼辦呢？

上圖為某公司產品傭金比例表。請查詢萬事興10年交、年年富貴20年交的傭金比例係數。

思路：我們要查詢某個產品的傭金比例，必須要結合產品名稱和繳費年限才能查詢，也就是綜合兩個條件的查詢。

方法一：輔助列法

在B列之後插入一列輔助列，在c2單元格輸入：=a2&b2，將產品名稱和繳費年限結合起來成為一個新欄位。然後在進行查詢。採用同樣的方法在H列之後插入一個輔助列，在I2單元格中輸入：=G2&H2

J2=VLOOKUP(I2,C:D,2,0)

該方法的原理是將兩個條件並為一個條件，然後再用vlookup進行查詢。

GIF動圖如下：

方法二：LOOKUP函數法

如果覺得用輔助列很麻煩的話，我們可以直接使用lookup函數來進行多條件一步到位查詢。

公式：H2=LOOKUP(1,0/($A$2:$A$10=F2)*($B$2:$B$10=G2),$C$2:$C$10)

公式解讀：lookup函數功能十分強大，在此我們用的是多條件查詢功能。其函數語法為：lookup（1,0/((查找條件1)*(查找條件2)*(查找條件3)...,查找區域）

GIF動圖：

方法三：VLOOKUP函數法

當然我們用vlookup函數也能進行多條件查詢，可以不需要設置輔助列，直接一步到位。

公式：H2=VLOOKUP(F2&G2,IF({1,0},$A$2:$A$10&$B$2:$B$10,$C$2:$C$10),2,0)

特別注意，這是數組公式，必須要按組合鍵：ctrl shift enter才能生效，否則會出錯。

公式解讀：IF({1,0},$A$2:$A$10&$B$2:$B$10,$C$2:$C$10)是通過數組{1,0}構造一個新的數據區域，以產品名稱加繳費期限合起來組建一個新欄位，傭金比例係數在後面，因此我們使用vlookup函數的第三個參數為2,。此公式是數組公式，函數比較複雜，運算效率比較低。

GIF動圖如下：

方法四：INDEX MATCH函數法

INDEX MATCH函數功能十分強大，也能進行多條件查找。我們在H2單元格輸入數組公式：=INDEX($C$2:$C$10,MATCH(F2&G2,$A$2:$A$10&$B$2:$B$10,))

該公式為數組公式，輸入完公式之後，要按組合鍵ctrl shift enter，才能生效，否則會出錯。

公式解讀：MATCH(F2&G2,$A$2:$A$10&$B$2:$B$10,)是用產品加繳費年限構成一個新欄位，然後將所有產品和繳費年限構成一個數組，用match函數去查位於第幾個位置，最後用index函數嵌套，得出最終的傭金比例。該公式較難，只要有庖丁解牛的精神，就能深入淺出理解，提升自我水平。

GIF動圖如下：

方法五：SUMPRODUCT函數法

SUMPRODUCT函數也能進行多條件查找，其語法為sumproduct（（條件1）*(條件2）*(條件3）...

公式H2=SUMPRODUCT(($A$2:$A$10=F2)*($B$2:$B$10=G2),$C$2:$C$10)

GIF動圖如下：

方法六：sumifs函數法

思路：經觀察，產品加繳費年限組成的新欄位就是唯一值，傭金比例是數字。因此我們用sumifs函數也能達到多條件查找的目的。

公式：H2=SUMIFS(C:C,A:A,F2,B:B,G2)

公式解讀：

SUMIFS函數功能

SUMIFS 函數用於計算單元格區域或數組中符合多個指定條件的數字的總和。

SUMIFS(sum_range,criteria_range1,criteria1,[criteria_range2],[criteria2],…)

參數說明

sum_range(必選)：表示要求和的單元格區域。

criteria_range1(必選)表示要作為條件進行判斷的第 1 個單元格區域。

criteria_range2,…(可選)：表示要作為條件進行判斷的第 2~127 個單元格區域。

GIF動圖如下：

特別提醒：讀者們必須要注意相對引用、絕對引用、混合引用之間的區別。

小夥伴們，操練起來吧。

推薦閱讀：